New projects | PLaSM | Alberto Paoluzzi

Logistic district

Wed, 26 Sep 2007 15:04:06 +0200

Model of a commercial district

In this section we discuss the development of some parameterized symbolic models of virtual warehousing buildings, that could be used by a security enforcement system to model the protection and the security of a logistics company. Our modeling design will be based on the elementary standardized items of such kind of building trade, i.e.~on the models of the pallet and of the storage rack.

Modular warehouse elements

In Listing 1 is given the PLaSM coding of the EUR-Epal pallet specification, shown in Figure 6a. Each layer is generated by Cartesian product of three 1D polyhedral complexes. The four wooden layers are stacked by the TOP operator, and finally the solid angles are subtracted to the model, named europallet. The single angle is generated by extrusion (Cartesian product by the 1D segment q:1.66) of the properly-scaled standard triangle simplex:2 of unit size.

DEF europallet =
        (layer4 TOP layer3 TOP layer2 TOP layer1) - angles
WHERE
        dy = (0.800 - 0.145*3 - 0.100*2)/4,
        layer1 = q:1.2 * q:<0.145,-:dy,0.1,-:dy,0.145,-:dy,0.1,-:dy,0.145> * q:0.022,
        layer2 = q:<0.145,-0.382,0.145,-0.382,0.145> * q:0.8 * q:0.022,
        layer3 = q:<0.145,-0.382,0.145,-0.382,0.145> * q:<0.1,-:(dy+0.045),-0.1,-:dy,0.145,-:dy,-0.1,-:(dy+0.045),0.1> * q:0.1,
        layer4 = q:1.2 * q:<0.1,-:(dy+0.045),-0.1,-:dy,0.145,-:dy,-0.1,-:(dy+0.045),0.1> * q:0.022,
        angle = S:<1,2>:<0.022,0.022>:(simplex:2) * q:1.66,
        angles = STRUCT:< angle,T:1:1.2 ~ S:1:-1,angle,T:2:0.8 ~ S:2:-1,angle,S:1:-1~T:1:-1.2,angle  >
END;
VIEW:europallet;

Europallet model

A deposit of pallets is generated by the code in Listing 2 and displayed in Figure 6c. The palletpile function concatenates n instances of the pair <europalette,T:3:0.166>, where T:3:0.166 is a z -translation of 0.166 meters, and assembles the pile according to the semantics of the PHIGS structures [iso/iec 9592-1 1989]. The europalette symbol contains a geometric value obtained by europallet by exchanging the x and y coordinates, according to the semantics of the MAP operator.

DEF palletpile(n::isintpos) =
        (STRUCT~##:n):<europalette,T:3:0.166>
WHERE
        europalette = MAP:[s2,s1,s3]:europallet
END;
DEF palletwall(n,m::isintpos) =
        (STRUCT~##:m):<palletpile:n,T:1:0.8>;
VIEW:(palletwall:<30,12>);

Palletwall instance

In Listing 3 we show the definition of a warehouse rack parameterized with respect to the number nn of floors, the number m of piles, the height, width, and depth of the single floor, and even to the geometry of the stored warehouse. The frame module is a structure of four column at the angles of the rack element, named theframe, which also contains two horizzontal elements hsupport and two pairs of diagonal elements dsupport1 and dsupport2. It may be useful to notice that dsupport2 is generated by applying a suitable vertex MAP to dsupport1, that reverses the sign of the x coordinates, and applies a linear map $y \mapsto depth •y$ to the y coordinates, while leaving the z coordinates invariant.

DEF warehouse_rack (nn,m::isintpos)(height,width,depth::isrealpos) (loading::ispol) =
        (STRUCT~##:m):< pile,T:1:(width+0.2)>
WHERE
        frame_module = STRUCT:< column,T:2:depth,column,T:1:width,column,T:2:(-:depth),column >,
        column = cylinder:<0.02,height>:12,
        hsupport = STRUCT:<T:1:-0.02,cuboid:<0.04,depth,0.02>>,
        dsupport1 = (R:<2,3>:(atan:(height/depth))~CUBOID):<0.01,SQRT:(height**2+depth**2),0.02>,
        dsupport2 = MAP:[-~S1,K:depth - S2,S3]:dsupport1,
        beams = q:width * (q~#:nbeams):0.1 * q:<-0.02,0.1> TOP loading,
        nbeams = FLOOR:(depth/0.1),
        theframe = STRUCT:<beams,frame_module ,dsupport1,dsupport2,hsupport,T:1:width,hsupport,dsupport1,dsupport2>,
        pile = (STRUCT~##:nn):<theframe,T:3:height> TOP top_pile,
        top_pile = STRUCT:<beams,hsupport,T:1:width,hsupport >
END;

In Listing 4 we show a possible definition for the loading of the warehouse rack, in this case given as a double pair, in turn assembled as a carton and an europallet oriented with the main axis along the y direction. The loading value defined here is the one used in Figures 7a and 7b.

DEF loading = STRUCT:< pair,T:1:1.2, pair >
WHERE
        pair = MAP:[s2,s1,s3]:europallet TOP carton,
        carton = CUBOID:<0.7,1.2,1.2>
END;
VIEW:(pallet_rack:<6,8>:<1.8,2.5,1.5>: loading);

The model shown in Figure 7c is generated by the PLaSM code in Listing 5. The warehouse function has the same interface than the warehouse rack function, but without the formal parameter loading of polyhedral type. The reader may see that the argument expression of the VIEW primitive is used to generate three warehouse instances with different actual parameter values, and to locate the 1st and 3rd instances below and on the left of the 2nd one, respectively. The reader should understand that a multiple infix expression like exp1 OP1 exp2 OP2 ex3 is evaluated from left-toright as ((exp1 OP1 exp2 ) OP2 ex3 ).

%DEF warehouse (nn,m::isintpos)
        (height,width,depth::isrealpos) = .... ;
VIEW:(warehouse:<3,4>:<1.8,2.5,1.5> STRUCT
        T:3:(1.8*3):(warehouse:<1,4>:<1.8,2.5,1.0>)
        LEFT T:1:0.2:(warehouse:<4,3>:<1.8,2,1.0>) );%

Warehouse buildings

In order to generate some nice models of very different warehouse buildings, we start by preparing a small geometric library, allowing for both realistic and fancy construction models. We have a double aim: (a) to generate some complex models by writing an extremely compact PLaSM code; (b) to show the amazing descriptive power of the language. In particular, we proceed in the following way. First, we generate three Coons' surfaces S, S, S: [0, 1]^2 \rightarrow E^3.

Then we linearly combine such surfaces pairwise, to generate two volume maps V0, V1: [0, 1]^3 \rightarrow E^3 that we will use to produce the columns and the beams, respectively, according to different engineering schemes for the resistant structure. Let us notice that a CoonsPatch is a surface generated by transfinite interpolation of 4 boundary curves u0,u1,v0,v1. Bezier is the PLaSM naming of the transfinite and multivariate B •ezier library function (see, e.g. [Paoluzzi 2003]). The physical dimensions of the building are defined by the parameters w,d,h of the surface function, which stand for width, depth, and height (in meters), respectively. The further parameters uw,ud,uh and vw,vd,vh are used to variate the geometry of the beams and the roof in the u, v directions of the domain space, and are all zero in the building of Figure 9a.

DEF surface(w,d,h::isreal)(uw,ud,uh::isreal)
        (vw,vd,vh::isreal) = CoonsPatch:<u0,u1,v0,v1>
WHERE
        u0 = bezier:s1:<<0,0,h>,<w/3,0,h+uh>,<2*w/3,0,h+uh>,<w,0,h>>,
        u1 = bezier:s1:<<0,d,h>,<w/3,d,h+uh>,<2*w/3,d,h+uh>,<w,d,h>>,
        v0 = bezier:s1:<<0,0,h>,<0,d/3,h+vh>,<0,2*d/3,h+vh>,<0,d,h>> (AA:COMP~DISTR) [S2],
        v1 = bezier:s1:<<w,0,h>,<w,d/3,h+vh>,<w,2*d/3,h+vh>,<w,d,h>> (AA:COMP~DISTR) [S2]
END;
DEF S_0 = surface:<40,16,0>:<0,0,0>:<0,0,0>;
DEF S_1 = surface:<40,16,10>:<0,0,-1>:<0,0,1.0>;
DEF S_2 = surface:<40,16,12>:<0,0,-2>:<0,0,2.0>;
DEF V0 = bezier:s3:< S_0, S_1 >;
DEF V1 = bezier:s3:< S_1, S_2 >;

The actual building shape is defined by suitably setting some subsets of the domain ^{3 of the volume maps V0 , V1 to accomodate the various building
fabric subsystems, i.e. columns, beams, roofs, enclosure1 and enclosure2, each
one defined as a Cartesian product of three 1D (set of) intervals. The resulting
building as a set of E3 points is just a STRUCT aggregation of the MAPped
subdomains of [0, 1]}3 . Figure 9 shows some examples.

DEF dom (n::isint; m::isrealpos) =
        ##:(n - 1):<full,-:empty> AR full
WHERE
        full = m/n, empty = (1- full*n)/(n - 1)
END;
DEF pattern = dom:<12,0.10>;
DEF columns = q:pattern * q:<0.05,-0.9,0.05>* q:1;
DEF beams = q:pattern * q:(#:20:0.05) * q:1;
DEF roofs = (q ~ aa:-):pattern * q:(#:20:0.05)
        * q:<-0.8,0.2>;
DEF enclosure1 = (q ~ aa:-):pattern
        * q:<0.01,-0.98,0.01> * q:<0.5,-0.5>;
DEF enclosure2 = (q ~ aa:-):pattern
        * q:<0.01,-0.98,0.01> * q:1;

DEF building1 = STRUCT:< MAP:V0:columns, MAP:V1:beams, MAP:V1:roofs, MAP:V0:enclosure1, MAP:V1: enclosure2%, deposit% >
WHERE
        S_0 = surface:<60,12,0>:<0,0,0>:<0,0,0>,
        S_1 = surface:<60,12,10>:<0,0,-1>:<0,0,1.0>,
        S_2 = surface:<60,12,12>:<0,0,-2>:<0,0,2.0>,
        V0 = bezier:S3:< S_0, S_1 >,
        V1 = bezier:S3:< S_1, S_2 >
END;
DEF building2 = STRUCT:< MAP:V0:columns, MAP:V1:beams, MAP:V1:roofs, MAP:V0:enclosure1, MAP:V1: enclosure2%, deposit% >
WHERE
        S_0 = surface:<60,12,0>:<0,0,0>:<0,0,0>,
        S_1 = surface:<60,12,10>:<0,0,-1>:<0,0,-1.0>,
        S_2 = surface:<60,12,12>:<0,0,-2>:<0,0,-2.0>,
        V0 = bezier:S3:< S_0, S_1 >,
        V1 = bezier:S3:< S_1, S_2 >
END;
DEF building3 = STRUCT:< MAP:V0:columns, MAP:V1:beams, MAP:V1:roofs, MAP:V0:enclosure1, MAP:V1: enclosure2%, deposit% >
WHERE
        S_0 = surface:<60,12,0>:<0,0,0>:<0,0,0>,
        S_1 = surface:<60,12,10>:<0,0,1>:<0,0,0>,
        S_2 = surface:<60,12,12>:<0,0,2>:<0,0,0>,
        V0 = bezier:S3:< S_0, S_1 >,
        V1 = bezier:S3:< S_1, S_2 >
END;
DEF building4 = STRUCT:< MAP:V0:columns, MAP:V1:beams, MAP:V1:roofs, MAP:V0:enclosure1, MAP:V1: enclosure2%, deposit% >
WHERE
        S_0 = surface:<60,12,0>:<0,0,0>:<0,0,0>,
        S_1 = surface:<60,12,10>:<0,0,0>:<0,0,1>,
        S_2 = surface:<60,12,12>:<0,0,0>:<0,0,2>,
        V0 = bezier:S3:< S_0, S_1 >,
        V1 = bezier:S3:< S_1, S_2 >
END;
DEF loading_rack = (T:1:20~R:<1,2>:(pi/2)~ warehouse_rack:<4,3>:<1.8,  2.5, 1.5>): loading;
DEF deposit = (STRUCT ~ ##:10):< loading_rack , T:1:3.6>;
VIEW: building1;

"building1" value

Simple road models

The function road in Listing 8 takes as input a polycurve output, i.e. a sequence of triples of control points, as well as a width w, and returns a solid model of the road having as axis the set of quadratic B •ezier curves produced by the control points. The set of roads of our model in generated by Listing 9.

DEF road(w::isreal) = STRUCT ~ aa:(stripe:<w,6>);
DEF stripe(width::IsReal;n::IsIntPos)
        (points::ismat) = MAP:coordFuncs:domain
WHERE
        coordFuncs = Bezier:s1:points vectsum (s2 scalarvectprod (Norm2 ~DerBezier):points),
        domain = (S:2:(width/2) ~ T:<1,2>:<1E-5,-1>):
                (Intervals:1:n * Intervals:2:1)
END;

DEF polycurve (radius::isreal) (points::ismat) = if:< gt:2 ~ len,
    cat ~ addExtremeLinearSegments
    ~ distributeLinearSegmentsBetweenQuadratic, id>  :points
WHERE
  addExtremeLinearSegments =
    [[[k:(first:points), s1~s1]], id, [[last~last, k:(last:points)]]],
  distributeLinearSegmentsBetweenQuadratic =
    rtail~cat~trans~[id,  ar~[trans~[rtail~s3, tail~s1]~trans, K:0]]
    ~ generateQuadraticSegments,
  generateQuadraticSegments = aa:(newpoints:radius) ~ triples,
  triples = trans~[rtail~rtail, tail~rtail, tail~tail],
  newpoints (b::isrealpos) (p1,p2,p3::ispoint) = <p12,p2,p23>
  WHERE
    v12 = p1 vectdiff p2,    v23 = p3 vectdiff p2,
    p12 = p2 vectsum (v12 scalarvectprod (b / vectnorm:v12)),
    p23 = p2 vectsum (v23 scalarvectprod (b / vectnorm:v23))
  END
END;

DEF road(width::isreal) =
        STRUCT ~ AA:(stripe:<width,6>);
DEF avenue1 = (road:6 ~ polycurve:10):
        <<0,0>,<0,-74>,<0,-148>>;
DEF avenue2 = (road:6 ~ polycurve:10):
        <<78,-12>,<78,-151>,<-78,-151>,<-78,-12>>;
DEF parking = (T:<1,2>:<3,-141> ~ CUBOID):
        <72,40,0.2>;
DEF road112 = (road:8 ~ polycurve:20):<<0,-160>,<-90,-160>,<-90,4>,<90+170,4>,<90+170,-180>,<90,-180>,<30,-160>,<0,-160>>;
DEF road01 = (STRUCT ~ AA:(road:8 ~ polycurve:20) ~ [ID, AA:[s1, C:+:-8 ~ s2]]):
        < <-190,-160>,<0,-160>,<30,-160>,<90,-180>,<260,-180>,<360,-180> >;
VIEW: road01;

"road01" value

The model of a commercial district

The VR model of a whole commercial district, including roads, service zones, parkings and several warehouse building with internal warehouse decks, merchandise containers, cartons and pallets is generated using the code discussed in the above subsections, as the value produced by the evaluation of the commercial district symbol, given in Listing 10 and shown in Figure 1. Such a virtual environment is very easy to set up or digitize, as it only requires a small set of points to define the control points of the road axes.

DEF triple(p::ispol) =
        (STRUCT ~ ##:3 ~ [ID, T:2 ~ SIZE:2]):p;
DEF double(b1,b2::ispol) =
        STRUCT:<T:<1,2>:<-75,-48>,b1,T:2:-48,b2>;
DEF avenue12 = STRUCT:<avenue1,avenue2,parking,
        S:1:-1:parking,
        (double ~ AA:triple):<building1,building2>,
        (S:1:-1 ~ double ~ AA:triple):<building3,building4> >;
DEF commercial_district = STRUCT:< road01,road112,avenue12,T:1:170,S:1:-1:avenue12 >;
VIEW:commercial_district;

Commercial district model

Leaning tower

Sat, 20 Jan 2007 05:47:19 +0100

Global parameters

DEF scalefactor = 3.16655256; DEF InternalBasementRadius = scalefactor*0.7; DEF ExternalBasementRadius = scalefactor*3.2; DEF BasementHeight = scalefactor*1.3; DEF WidthBasement = ExternalFirstFloorRadius - InternalFirstFloorRadius; DEF InternalFirstFloorRadius = scalefactor*1.2; DEF ExternalFirstFloorRadius = scalefactor*2.5; DEF InternalWallRadius = scalefactor*1.25; DEF ExternalWallRadius = scalefactor*2.1; DEF FirstFloorHeight = 3.15 * scalefactor; DEF WallHeight = 9.35 * scalefactor; DEF FirstRingPerimeter = 5.15 * scalefactor * PI; DEF FirstRingColumnArcWidth = FirstRingPerimeter/12; DEF ColumnScaling = (WallHeight/6)/(size:3:(Column_1:(pi/24)));

Tower basement

DEF basament1 = (Cylinder:<ExternalBasementRadius,BasementHeight/2>:24) - (Cylinder:<InternalBasementRadius,BasementHeight/2>:24); DEF basament2 = thebasament - cone2 WHERE thebasament = basament1 & cone1, cone1 = cone:<ExternalBasementRadius,hcone>:24, hcone = tg_alpha * ExternalBasementRadius, tg_alpha = (ExternalBasementRadius - ExternalFirstFloorRadius)/(BasementHeight/2), reversed_cone = S:3:-1:cone1, cone2 = T:3:tcone:reversed_cone, tcone = tg_alpha * (ExternalBasementRadius - InternalBasementRadius) END; DEF Basament = STRUCT:< basament1, T:3:(BasementHeight/2):basament2 >;

Tower kernel

DEF FirstFloor = Cylinder:<ExternalFirstFloorRadius,FirstFloorHeight>:24 - Cylinder:<InternalFirstFloorRadius,FirstFloorHeight>:24; DEF Kernel = Cylinder:<ExternalWallRadius,WallHeight>:24 - Cylinder:<InternalWallRadius,WallHeight>:24;

Tower terrace

DEF Terrace = (T:3:(0.095*scalefactor/2) ~ STRUCT):< S:3:-1:wafer1, wafer1> WHERE wafer1 = terrace1 & cone1, terrace1 = Cylinder:<1.1*ExternalFirstFloorRadius, 0.095*scalefactor/2>:24 - Cylinder:<ExternalWallRadius, 0.095*scalefactor/2>:24, hcone = tg_alpha * 1.1*ExternalFirstFloorRadius, tg_alpha = (0.05*ExternalFirstFloorRadius)/(0.095*scalefactor), cone1 = cone:<1.1*ExternalFirstFloorRadius, hcone>:24 END;

First tower ring

DEF Column_1 (angle::isreal) = (optimize~R:<1,2>:(angle) ~T:<1,2,3>:<2.6*scalefactor,0,-0.2*scalefactor>): (box TOP basis TOP fusto TOP basis TOP capitello TOP box1) WHERE unit = FirstRingColumnArcWidth/2, basis = Cylinder:<0.11*scalefactor,0.03*scalefactor>:18, fusto = Cylinder:<0.095*scalefactor,1.75*scalefactor>:18, capitello = truncone:<0.09*scalefactor,0.14*scalefactor,0.18*scalefactor>:18, box = (T:<1,2>:<-0.15*scalefactor,-0.15*scalefactor>~cuboid): <0.30*scalefactor,0.30*scalefactor,0.28*scalefactor>, box1 = cuboid:<0.30*scalefactor,0.30*scalefactor,0.05*scalefactor> END;

Other tower rings

DEF Column_2 (angle::isreal) = (optimize~R:<1,2>:(angle) ~T:<1,2,3>:<2.53*scalefactor,0,0.09*scalefactor>): (S:3:columnscaling:( box0 TOP basis0 TOP basis1 TOP basis2 TOP fusto TOP basis2 TOP capitello) align:<<1,max,max>,<2,med,med>,<3,max,min>> box1) WHERE unit = FirstRingColumnArcWidth/2, transl = T:<1,2>:<-0.12*scalefactor,-0.12*scalefactor>, box0 = (transl~cuboid): <0.24*scalefactor,0.24*scalefactor,0.06*scalefactor>, basis0 = Cylinder:<0.11*scalefactor,0.02*scalefactor>:18, basis1 = Cylinder:<0.08*scalefactor,0.04*scalefactor>:18, basis2 = Cylinder:<0.09*scalefactor,0.02*scalefactor>:18, fusto = Cylinder:<0.07*scalefactor,1.40*scalefactor>:18, capitello = truncone:<0.07*scalefactor,0.10*scalefactor,0.16*scalefactor>:18, box1 = MKPOL:<<<0,y,0>,<0,-:y,0>,<x,y - dy,0>,<x,dy - y,0>, <0,y,z>,<0,-:y,z>,<x,y - dy,z>,<x,dy - y,z>>,<1..8>,<(1)>> WHERE y = 0.13*scalefactor, x = -4*y, z = y, dy = tan:(pi/36)*(-:x) END END;

Arcs of first ring

DEF Arch (r1,r2,w::IsRealPos) = (optimize~R:<1,3>:(pi/-2)~T:3:(w/-2)~STRUCT):< (Cylinder:<r2,w>:24 - (Cylinder:<r1,w>:24 + (T:2:(-:r2)~CUBOID):<r2,2*r2,w>)) , (T:2:(-:r2)):(CUBOID:<r2*sin:(pi/12),2*r2,w>) - (T:2:(-:r1)):(CUBOID:<r2*sin:(pi/12),2*r1,w>) > ; DEF Arc_1_1 = T:<1,2,3>:<2.45*scalefactor,0,2.30*scalefactor>: ((Arch:< 0.8*unit, unit, unit/2 >) STRUCT (Arch:< unit, 1.05*unit, unit/1.5 >)) WHERE unit = FirstRingColumnArcWidth/2 END; DEF Wall_1 = T:3:(2.30*scalefactor): (TheCylinder - Ottusangle - Hole:<1.05*unit, unit/1.5> ) WHERE unit = FirstRingColumnArcWidth/2, TheCylinder = Cylinder:<1.08*ExternalFirstFloorRadius, 1.1*unit>:24 - Cylinder:<ExternalWallRadius, 1.1*unit>:24, Ottusangle = ((optimize~R:<1,2>:(pi/12)~T:1:(-100)~CUBOID):<200,100,100> + (optimize~R:<1,2>:(11*pi/12)~T:1:(-100)~CUBOID):<200,100,100> ), Hole (r2,w::isrealpos) = (T:<1,2>:<2.45*scalefactor,0>):( (R:<1,3>:(pi/-2)~S:3:2~T:3:(w/-2)):(Cylinder:<r2,2*w>:24 - (T:2:(-:r2)~CUBOID):<r2,2*r2,w>) ) END; DEF FirstColumnRing = (STRUCT ~ ##:12):< Column_1:(pi/12), Arc_1_1, Wall_1, R:<1,2>:(pi/6) >;

Arcs of other rings

DEF Arc_2_1(angle::isreal) = (optimize~R:<1,2>:(angle)~T:<1,2,3>: <2.40*scalefactor,0,2.10*scalefactor*columnscaling>): ((Arch:< 0.65*unit, 0.9*unit, 1.5*unit >) STRUCT (Arch:< 0.9*unit, unit, unit/0.75 >)) WHERE unit = FirstRingColumnArcWidth/4 END; DEF Wall_2 (angle::isreal) = (optimize~R:<1,2>:(angle)~T:3:(2.10*scalefactor*columnscaling)): (TheCylinder - Ottusangle - Hole:<unit, unit/0.75> ) WHERE unit = FirstRingColumnArcWidth/4, TheCylinder = Cylinder:<1.05*ExternalFirstFloorRadius, 1.35*unit>:48 - Cylinder:<ExternalWallRadius, 1.35*unit>:24, Ottusangle = ((optimize~R:<1,2>:(pi/24)~T:1:(-100)~CUBOID):<200,100,100> + (optimize~R:<1,2>:(23*pi/24)~T:1:(-100)~CUBOID):<200,100,100> ), Hole (r2,w::isrealpos) = (T:<1,2>:<2.45*scalefactor,0>):( (R:<1,3>:(pi/-2)~S:3:2~T:3:(w/-2)):(Cylinder:<r2,2*w>:24 - (T:2:(-:r2)~CUBOID):<r2,2*r2,w>) ) END; DEF SecondColumnRing = (STRUCT ~ ##:24):< Column_2:(pi/12), Arc_2_1:(pi/24), Wall_2:(pi/24), R:<1,2>:(pi/12) >;

Internal steps

DEF radiusSteps = 1.9 * scalefactor; DEF pitchSteps = (7/1.5) * scalefactor; DEF angleSteps = 21*pi/4 ; DEF numberOfSteps = 293; DEF alphaStep = -:angleSteps/numberOfSteps; DEF zetaStep = (FirstFloorHeight+WallHeight)/numberOfSteps; DEF stepVolume = (T:1:(-:radiusSteps)~CUBOID):(<0.4,0.11,0.8> scalarvectprod scalefactor); DEF stepsSegment = (optimize~STRUCT~CAT~TRANS): < translations, rotations, objects > WHERE translations = #:17:(T:3:zetaStep), rotations = #:17:(R:<1,2>:alphaStep), objects = #:17:stepVolume END; DEF steps = (optimize~STRUCT~##:17):< stepsSegment, R:<1,2>:(17*alphaStep), T:3:(17*ZetaStep) >; DEF fabric = STRUCT:< T:3:(-:BasementHeight):Basament, Steps color Red, FirstFloor, T:3:FirstFloorHeight:Kernel, FirstColumnRing, T:3:(FirstFloorHeight - 0.095*scalefactor), Terrace, (STRUCT ~ ##:5):< SecondColumnRing, T:3:(WallHeight/5), Terrace >, >;

Tower cap

DEF lastFloorHeight = WallHeight/5; DEF TowerCap = lastWall STRUCT ((T:3:lastFloorHeight~JOIN~truncone:< ExternalFirstFloorRadius, ExternalWallRadius, 0.4*scalefactor >):24 - Join:(MySphere:externalWallRadius:<12,24>)) WHERE lastWall = Cylinder:<ExternalWallRadius,lastFloorHeight>:24 - Cylinder:<InternalWallRadius,lastFloorHeight>:24 END; DEF MySphere (radius::IsRealPos)(n,m::IsIntPos) = MAP:[fx,fy,fz]:domain WHERE fx = K:radius * - ~ SIN ~ S2 * COS ~ S1, fy = K:radius * COS ~ S1 * COS ~ S2, fz = K:radius * SIN ~ S1, domain = (Intervals:PI:n * Intervals:(2*PI):m) END; DEF fabric = STRUCT:< T:3:(-:BasementHeight):Basament, Steps color Red, FirstFloor, T:3:FirstFloorHeight:Kernel, FirstColumnRing, T:3:(FirstFloorHeight - 0.095*scalefactor), Terrace, (STRUCT ~ ##:6):< SecondColumnRing, T:3:(WallHeight/5), Terrace >, T:3:(WallHeight), TowerCap >;

Tower cap (seventh order)

DEF Int7Height = scalefactor*1.7; DEF Ext7Height = scalefactor*2.3; DEF c11 = bezier:s1:<<InternalWallRadius,0,0>,<InternalWallRadius,0,Int7Height>>; DEF c12 = bezier:s1:<<ExternalWallRadius,0,0>,<ExternalWallRadius,0,Ext7Height>>; DEF surf1 = bezier:s2:<c11,c12>; DEF c21 = hermite:<<InternalWallRadius,0,Int7Height>,<0.75,0,Ext7Height - 0.25>,<-1,0,2.5>,<-3,0,0>>; DEF c22 = bezier:s1:<<ExternalWallRadius,0,Ext7Height>,<0.75,0,Ext7Height>>; DEF surf2 = bezier:s2:<c21,c22>; DEF c31 = bezier:s1: <<ExternalWallRadius,0,Int7Height>,<ExternalWallRadius,0,Ext7Height>>; DEF c32 = bezier:s1: <<ExternalWallRadius+1,0,Int7Height>, <ExternalWallRadius+1,0,(Int7Height +Ext7Height)/2>>; DEF surf3 = bezier:s2:<c31,c32>; DEF solid (surf::isvect) = < (s1:surf * cos~s3) - (s2:surf * sin~s3), (s2:surf * cos~s3) + (s1:surf * sin~s3), s3:surf >; DEF out1 = MAP:(solid:surf1):(intervals:1:1 * intervals:1:1 * intervals:(3*pi/2):18); DEF out2 = MAP:(solid:surf2):(intervals:1:9 * intervals:1:1 * intervals:(3*pi/2):18); DEF out3 = MAP:(solid:surf3):((sqr~intervals:1):1 * intervals:(3*pi/2):18); DEF cap = STRUCT:<out1,out2,out3>;

Tower bell

DEF Column_b = (optimize ~T:<1,2,3>:< (-18/24)*2.53*scalefactor,0,0.09*scalefactor>): (S:3:columnscaling:( box0 TOP basis0 TOP basis1 TOP basis2 TOP fusto TOP basis2 TOP capitello) align:<<1,max,max>,<2,med,med>,<3,max,min>> box1) WHERE unit = FirstRingColumnArcWidth/2, transl = T:<1,2>:<-0.12*scalefactor,-0.12*scalefactor>, box0 = (transl~cuboid):<0.24*scalefactor,0.24*scalefactor,0.06*scalefactor>, basis0 = Cylinder:<0.11*scalefactor,0.02*scalefactor>:18, basis1 = Cylinder:<0.08*scalefactor,0.04*scalefactor>:18, basis2 = Cylinder:<0.09*scalefactor,0.02*scalefactor>:18, fusto = Cylinder:<0.07*scalefactor,1.40*scalefactor>:18, capitello = truncone:<0.07*scalefactor,0.10*scalefactor,0.16*scalefactor>:18, box1 = box0 END; DEF Arc_2_b = (optimize~R:<1,2>:(pi/18)~T:<1,2,3>: <(18/ 24)*2.53*scalefactor,0,2.08*scalefactor*columnscaling>): (Arch:< 0.65*unit, 0.9*unit, 0.5*unit > STRUCT Arch:< 0.9*unit, 1.1*unit, 0.65*unit > ) WHERE unit = FirstRingColumnArcWidth/4 END; DEF Wall_b (angle::isreal) = (optimize~R:<1,2>:(angle) ~ T:3:((18/ 24)*2.10*scalefactor*columnscaling)): (TheCylinder - Ottusangle - Hole:<unit, unit/0.75> ) WHERE unit = FirstRingColumnArcWidth/4, TheCylinder = Cylinder:<1.05*ExternalFirstFloorRadius, 1.35*unit>:48 - Cylinder:<ExternalWallRadius, 1.35*unit>:24, Ottusangle = ((optimize~R:<1,2>:(pi/24)~T:1:(-100)~CUBOID):<200,100,100> + (optimize~R:<1,2>:(23*pi/24)~T:1:(-100)~CUBOID):<200,100,100> ), Hole (r2,w::isrealpos) = (T:<1,2>:<2.45*scalefactor,0>):( (R:<1,3>:(pi/-2)~S:3:2~T:3:(w/-2)):(Cylinder:<r2,2*w>:24 - (T:2:(-:r2)~CUBOID):<r2,2*r2,w>) ) END; DEF TopTower = STRUCT:< SecondColumnRing, cap, T:3:(WallHeight/5), Terrace>;

Belt Tower

DEF tooth = (optimize~STRUCT):< lungo, R:<1,2>:(pi/106), corto > where raggio = ExternalWallRadius, lungo = mymap1:<0,0.1> TOP mymap2:<0.1,0.1>, corto = mymap2:< -0.05,0.2>, mymap1 (dr,h::isreal) = MAP:<(s2+s3)*cos~s1,(s2+s3)*sin~s1,s3>: (intervals:(pi/106):1 * T:1:(InternalWallRadius):(intervals:(width:dr):1) * intervals:h:1), mymap2 (dr,h::isreal) = MAP:<(s2)*cos~s1,(s2)*sin~s1,s3>:(intervals:(pi/106):1 * T:1:(InternalWallRadius):(intervals:(width:dr):1) * intervals:h:1), width(dr::isreal) = ExternalWallRadius - InternalWallRadius + dr end; DEF plateau = (optimize~STRUCT~##:106):<tooth,R:<1,2>:(2*pi/106)>; DEF BeltColumnRing = (STRUCT ~ ##:6): < Column_b, Arc_2_b, R:<1,2>:(pi/9),Column_b, Arc_2_b, R:<1,2>:(pi/9), Arc_2_b, R:<1,2>:(pi/9) > STRUCT T:3:5.75:plateau; DEF BeltWalls = MyRing:(3*pi/9): <InternalWallRadius,ExternalWallRadius*6/7>:<6,1> * Q:5.75; DEF SmallWindow1 = MyRing:((3*pi)/(18*4)): <InternalWallRadius - 1,ExternalWallRadius*6/7 + 1>:<2,1> * Q:1.75; DEF SmallWindow2 = MyRing:((4*pi)/(18*5) + pi/64): <InternalWallRadius - 1,ExternalWallRadius*6/7 + 1>:<2,1> * Q:<-1.75,-0.35,2>; DEF MyRing (angle::IsReal)(r1,r2::IsRealPos)(n,m::IsIntPos) = MAP:[s2 * cos ~ S1, s2 * sin ~ S1]:domain WHERE domain = T:2:r1:(Intervals:angle:n * Intervals:(r2 - r1):m) END; DEF hole3 (angle::IsReal)(r1,r2::IsRealPos) = MAP: (Bezier:S3:([portal1:(angle), portal2:(angle)]:<r1,r2>)): (intervals:1:1 * intervals:1:12 * intervals:1:1) WHERE portal1(angle::IsReal)(r1,r2::IsRealPos) = CubicHermite:S2:< c1,c2,t1,t2 >, portal2(angle::IsReal)(r1,r2::IsRealPos) = Bezier:S2:< c1,c2 > vectsum <K:0,K:0,K:-0.1>, c1 = Bezier:S1:line1, line1 = <<r1,0,0>,<r2,0,0>>, c2 = Bezier:S1:line2, line2 = AA:(UK ~ R:<1,2>:angle ~ MK):line1, t1 = Bezier:S1:<<0,0,2>,<0,0,4>>, t2 = Bezier:S1:<<0,0,-2>,<0,0,-4>> END; DEF Window3 = MyRing:(2*pi/9 - 0.2): <InternalWallRadius - 1,ExternalWallRadius*6/7 + 1>:<1,1> * Q:2.5; DEF Hole3 = (T:3:(2.5)~R:<1,2>:(0.15/2)):(hole3:(pi/9): <InternalWallRadius - 1,ExternalWallRadius*6/7 + 1 >); DEF BeltTower = (STRUCT~##:6):<SectorWall,R:<1,2>:(pi/3)> STRUCT BeltColumnRing; DEF SectorWall = -:< BeltWalls, R:<1,2>:((3*pi)/(18*5)):SmallWindow1, R:<1,2>:(pi/36):SmallWindow2, R:<1,2>:(pi/9 + 0.1):Window3 > % STRUCT (R:<1,2>:(pi/9 + 0.1):Hole3 color red) % ;

Final tower assembly

DEF fabric = STRUCT:< T:3:(-:BasementHeight):Basament, Steps color Red, FirstFloor, T:3:FirstFloorHeight:Kernel, FirstColumnRing, T:3:(FirstFloorHeight - 0.095*scalefactor), Terrace, (STRUCT ~ ##:5):< SecondColumnRing, T:3:(WallHeight/5), Terrace >, T:3:WallHeight, TowerCap, TopTower, T:3:(max:3:TowerCap - 0.3), BeltTower >; view:fabric;

% export:(fabric):~/plasm/wrl/pisa.wrl; %

Last updated 27-Sep-2007 19:52:49 CEST

New projects | PLaSM | Alberto Paoluzzi

Logistic district

Modular warehouse elements

Warehouse buildings

Simple road models

The model of a commercial district

Leaning tower

Leaning tower of Pisa

Global parameters

Tower basement

Tower kernel

Tower terrace

First tower ring

Other tower rings

Arcs of first ring

Arcs of other rings

Internal steps

Tower cap

Tower cap (seventh order)

Tower bell

Belt Tower

Final tower assembly